%PDF- %PDF-
Mini Shell

Mini Shell

Direktori : /usr/share/systemtap/examples/io/
Upload File :
Create Path :
Current File : //usr/share/systemtap/examples/io/deviceseeks.stp

#!/usr/bin/stap
#
# Copyright (C) 2010 Red Hat, Inc.
# By Dominic Duval, Red Hat Inc.
# dduval@redhat.com
#
# Keeps track of seeks on devices.
# Shows how to use hist_log.
#  
# USAGE: stap deviceseeks.stp
#

global seeks, oldsec

probe ioblock_trace.request {
  if (size == 0) next
  %( $# == 1 %? if (devname !~ @1) next %) // reject mismatching device names
  sectorsize = (@defined($q->limits->logical_block_size)
		? $q->limits->logical_block_size
		: (@defined($q->logical_block_size) ? $q->logical_block_size
		   : $q->hardsect_size))
  # printf("%s %s\n", devname, rw ? "w" : "r")
  sec = sector
  seeks[devname] <<< sec - oldsec[devname]
  oldsec[devname] = sector + (size/sectorsize)
}

probe timer.s(10), end, error {
  printf("\n")
  foreach ([devname] in seeks- limit 5) {
    printf("Device: %s\n", devname)
    println(@hist_log(seeks[devname]))
  }
  delete seeks
}

Zerion Mini Shell 1.0